Ιδιοτιμές - Ιδιοσυναρτήσεις

Ακριβής επίλυση

Απλό παράδειγμα.

Clear["Global`*"]
operator = -Laplacian[u[x], {x}] + x^2 u[x]
bound = DirichletCondition[u[x] == 0, True]
DEigensystem[{operator, bound}, u[x], {x, -Infinity, Infinity}, 3]

Πιο σύνθετο παράδειγμα:

$u''(x)=\lambda u(x)$

$u(0)=0=u'(L)$

Clear["Global`*"]
L = Pi;
B1 = DirichletCondition[u[x] == 0, x == 0];
B2 = NeumannValue[0, x == L];

{idiotimes, idiosynartiseis} = 
  DEigensystem[{-Laplacian[u[x], {x}] + B2, B1}, u[x], {x, 0, L}, 10];
idiotimes
idiosynartiseis
Plot[idiosynartiseis, {x, 0, L}, PlotLegends -> idiosynartiseis]

{\frac{1}{4},\frac{9}{4},\frac{25}{4},\frac{49}{4},\frac{81}{4},\frac{121}{4},\frac{169}{4},\frac{225}{4},\frac{289}{4},\frac{361}{4}}

{\sin(\frac{x}{2}),\sin(\frac{3 x}{2}),\sin(\frac{5 x}{2}),\sin(\frac{7 x}{2}),\sin(\frac{9 x}{2}),\sin(\frac{11 x}{2}),\sin(\frac{13 x}{2}),\sin(\frac{15 x}{2}),\sin(\frac{17 x}{2}),\sin(\frac{19 x}{2})}

$Sin[x/2]$

$Sin[(3 x)/2]$

$Sin[(5 x)/2]$

$Sin[(7 x)/2]$

$Sin[(9 x)/2]$

$Sin[(11 x)/2]$

$Sin[(13 x)/2]$

$Sin[(15 x)/2]$

$Sin[(17 x)/2]$

$Sin[(19 x)/2]$

Κανονικοποίηση

Αυτόματη

Πρώτες 10 ιδιοτιμές-ιδιοσυναρτήσεις:

{idiotimesNorm, idiosynartiseisNorm} = 
  DEigensystem[{-Laplacian[u[x], {x}] + B2, B1}, u[x], {x, 0, L}, 10, Method -> "Normalize"];
{idiotimesNorm, idiosynartiseisNorm} // Transpose // TableForm

\begin{pmatrix} \frac{1}{4} & (\sqrt{\frac{2}{\pi }}) \sin(\frac{x}{2}) \\ \frac{9}{4} & (\sqrt{\frac{2}{\pi }}) \sin(\frac{3 x}{2}) \\ \frac{25}{4} & (\sqrt{\frac{2}{\pi }}) \sin(\frac{5 x}{2}) \\ \frac{49}{4} & (\sqrt{\frac{2}{\pi }}) \sin(\frac{7 x}{2}) \\ \frac{81}{4} & (\sqrt{\frac{2}{\pi }}) \sin(\frac{9 x}{2}) \\ \frac{121}{4} & (\sqrt{\frac{2}{\pi }}) \sin(\frac{11 x}{2}) \\ \frac{169}{4} & (\sqrt{\frac{2}{\pi }}) \sin(\frac{13 x}{2}) \\ \frac{225}{4} & (\sqrt{\frac{2}{\pi }}) \sin(\frac{15 x}{2}) \\ \frac{289}{4} & (\sqrt{\frac{2}{\pi }}) \sin(\frac{17 x}{2}) \\ \frac{361}{4} & (\sqrt{\frac{2}{\pi }}) \sin(\frac{19 x}{2}) \end{pmatrix}

Στο χέρι

(*Εδώ έχουμε το σύνηθες εσωτρικό γινόμενο, αφού είναι σε μορφή Sturm-Liouville*)
eigFnorms = Table[Sqrt[Integrate[idiosynartiseis[[n]]^2, {x, 0, L}]], {n, 1, 10}]

{\sqrt{\frac{\pi }{2}},\sqrt{\frac{\pi }{2}},\sqrt{\frac{\pi }{2}},\sqrt{\frac{\pi }{2}},\sqrt{\frac{\pi }{2}},\sqrt{\frac{\pi }{2}},\sqrt{\frac{\pi }{2}},\sqrt{\frac{\pi }{2}},\sqrt{\frac{\pi }{2}},\sqrt{\frac{\pi }{2}}}

idiosynartiseisNorm2 = Table[idiosynartiseis[[n]]/eigFnorms[[n]], {n, 1, 10}];
TableForm[idiosynartiseisNorm2]

\begin{pmatrix} (\sqrt{\frac{2}{\pi }}) \sin(\frac{x}{2}) \\ (\sqrt{\frac{2}{\pi }}) \sin(\frac{3 x}{2}) \\ (\sqrt{\frac{2}{\pi }}) \sin(\frac{5 x}{2}) \\ (\sqrt{\frac{2}{\pi }}) \sin(\frac{7 x}{2}) \\ (\sqrt{\frac{2}{\pi }}) \sin(\frac{9 x}{2}) \\ (\sqrt{\frac{2}{\pi }}) \sin(\frac{11 x}{2}) \\ (\sqrt{\frac{2}{\pi }}) \sin(\frac{13 x}{2}) \\ (\sqrt{\frac{2}{\pi }}) \sin(\frac{15 x}{2}) \\ (\sqrt{\frac{2}{\pi }}) \sin(\frac{17 x}{2}) \\ (\sqrt{\frac{2}{\pi }}) \sin(\frac{19 x}{2}) \end{pmatrix}

Αριθμητική επίλυση

Πρώτες 10 ιδιοτιμές-ιδιοσυναρτήσεις

{idiotimesN, idiosynartiseisN} = 
  NDEigensystem[{-Laplacian[u[x], {x}] + B2, B1}, u[x], {x, 0, L}, 10];
idiotimesN
Plot[idiosynartiseisN, {x, 0, L}]

{0.25000001320782783`,2.2500096036205375`,6.250204788035188`,12.251530300289064`,20.25684411474994`,30.272537991981974`,42.310533899704936`,56.39054304212703`,72.54246904683914`,90.80883095844446`}